[gom引擎]版本账号角色交易出售功能脚本说明

首先要开启角色交易功能；
打开M2引擎-选项-功能设置-其他控制(3)-勾选开启角色交易；

打开M2引擎-管理-角色交易管理；

以下是脚本：

(@InPutString @InPutInteger)
[@main]
角色在出售时，无法登录游戏，如果想要登录，必须取消出售\
<我要出售当前角色，不需要设置委托人|254#自动设置当前账号下的另外一个角色为委托人^254#不需要委托人在线，也不需要委托人同意/@角色出售>\
<我要出售当前角色，需要设置委托人|254#委托人必须在线，并且同意委托请求/@@InPutString1(请输入委托人名称，委托人必须在线，并且同意委托请求：)>\ \

<取消我账号下正在出售的角色/@取消出售>\
<取消正在出售的角色，委托人是我/@@InPutString2(请输入出售角色的名称，委托人必须是你才能取消：)>\
<取消正在出售的角色，不检测委托人/@@InPutString3(请输入出售角色的名称：)>\ \

<我要购买角色/@打开角色交易窗口>\

[@取消出售]
#if
#act
;CancelSellChar 是否检测委托人(0不检测 1检测) 正在出售的角色名称(可以为空，为空表示自己账号下的另外一个角色)
CancelSellChar

[@InPutString2]
#if
NOT EQUAL S2
#act
;CancelSellChar 是否检测委托人(0不检测 1检测) 正在出售的角色名称(可以为空，为空表示自己账号下的另外一个角色)
CancelSellChar 1 S2
#elseact
SENDMSG 6 你输入正确的名称

[@InPutString3]
#if
NOT EQUAL S3
#act
;CancelSellChar 是否检测委托人(0不检测 1检测) 正在出售的角色名称(可以为空，为空表示自己账号下的另外一个角色)
CancelSellChar 0 S3
#elseact
SENDMSG 6 你输入正确的名称

[@打开角色交易窗口]
#if
#act
OpenSellCharDlg

[@角色出售]
#act
;SellChar 出售货币类型(0-5，0=元宝 1=泡点 2=金币 3=金刚石 4=灵符 5=声望) 价格 委托人名称(如果为空表示使用该账号下另外一个角色作为委托人)
SellChar 0 100

[@InPutString1]
#if
NOT S1.checkOnline
#act
SENDMSG 6 你输入的委托人不在线
break

#if
NOT S1.INSAFEZONE
;检测一下委托人是否在安全区，防止玩家恶意输入委托人，弹窗委托人
#act
SENDMSG 6 委托人必须在安全区
break

;----------------------------------------------------------------------------
;----------------以下检测 是否和委托人面对面站着，可用可不用-----------
;----------------------------------------------------------------------------
#if
#act
GETPOSENAME S2

#if
NOT CompareText S1 S2
;检测一下是否和委托人面对面站着，防止玩家恶意输入委托人，弹窗委托人
#act
SENDMSG 6 必须和委托人面对面站着
break
;----------------------------------------------------------------------------
;----------------以上检测 是否和委托人面对面站着，可用可不用-----------
;----------------------------------------------------------------------------

#if
#act
;SellChar 出售货币类型(0-5，0=元宝 1=泡点 2=金币 3=金刚石 4=灵符 5=声望) 价格 委托人名称(如果为空表示使用该账号下另外一个角色作为委托人)
SellChar 0 100 S1
SENDMSG 6 请通知你的委托人同意委托请求

;-----------------------------------------------------------------------------------------------------------------------------
;---------------------------------------------------以下是QFunction-0脚本的相关触发-------------------------------------
;-----------------------------------------------------------------------------------------------------------------------------

;----------------------------------点击查看其他信息触发-----------------------------
[@SellCharOther]
;当前对象变量和常量的使用:\
;所有私人的常量都可以使用在前面加“C.”的方式\
;所有私人的变量使用<$CSTR(S1)>和查看自己的变量<$STR(S1)>多一个“C”\
;比如在攻击触发，被攻击触发，死亡触发，还有这里的查看出售角色的触发，都归类到当前对象\ \

该角色的名称:<$C.USERNAME>\
该角色的等级:<$C.LEVEL>\
该角色的元宝:<$C.GAMEGOLD>\
该角色的“T1”变量值:<$CSTR(T1)>\
该角色的“U1”变量值:<$CSTR(U1)>\
该角色的“S$自定义”的变量值:<$CSTR(S$自定义)> 如果该角色不在线，这个变量值是查不到的\

;----------------------------------购买角色成功脚本触发-----------------------------
[@SellCharBuyOK]
角色购买成功\ \
使用的货币类型:<$SELLCHARMONEYTYPE>\
使用的货币类型名称:<$SELLCHARMONEYTYPENAME>\
购买的价格:<$SELLCHARPRICE>\
委托人:<$SELLCHARPAYEE>\
购买的角色:<$CURRRTARGETNAME>\
卖家实际收到的款，也就是税后的:<$SELLCHARAFTERTAXPRICE>\

;----------------------------------角色出售的脚本触发-----------------------------
[@SellCharOK]
已经成功放入角色交易商店里出售，已退出游戏，\
在下线触发里加上离线脚本命令，可以使出售的人物离线挂机\

[@SellCharing]
正在出售中，不要重复操作

[@SellCharDeny]
对方拒绝了你的委托

[@SellCharMaxCount]
您的角色今天的出售次数已经超出限制，请明天在试

[@SellCharNoCommissioned]
你的账号下只有一个可用角色，没有角色可以做委托人


[@SellCharError1]
非法操作

[@SellCharError2]
委托人不能是自己，请重新选择其他角色

[@SellCharError3]
委托的角色不在线，请通知委托人上线，确认同意委托


[@SellCharError4]
该委托人不能委托，错误信息4

[@SellCharError5]
该委托人不能委托，错误信息5

[@SellCharError6]
正在等待委托人确认，请稍后

[@SellCharError7]
该委托人正在接受其他人的委托

[@SellCharError8]
正在等待委托人确认，请稍后


;取消角色出售的脚本触发

[@CancelSellCharOK]
取消出售成功

[@CancelSellCharSelling]
该角色正在取消出售，请稍后

[@CancelSellCharing]
该角色正在交易，请稍后

[@CancelSellCharSelling2]
你的账号下有角色正在取消出售，请稍后

[@CancelSellCharing2]
你的账号下有角色正在交易，请稍后

[@CancelSellCharNoFind]
你的账号下没有找到出售的角色

[@CancelSellCharCommissionedError]
你要取消出售的角色的委托人不是你，需要委托人来取消

[@CancelSellCharError1]
你的角色正在出售中，请稍后操作

[@CancelSellCharError2]
需要取消出售角色名称不正确

[@CancelSellCharError3]
已经取消出售了

[@CancelSellCharError4]
取消出售角色出错